nixos/pkgs/gruvbox-material-gtk.nix

{
  lib,
  stdenv,
  fetchFromGitHub,
  gtk3,
  breeze-icons,
  hicolor-icon-theme,
  hiDPI ? false,
}: let
  name = "gruvbox-material-gtk";
  rev = "cc255d43322ad646bb35924accb0778d5e959626";
  sha256 = "1O34p9iZelqRFBloOSZkxV0Z/7Jffciptpj3fwXPHbc=";

  variant =
    if hiDPI
    then "Gruvbox-Material-Dark-HIDPI"
    else "Gruvbox-Material-Dark";
in
  stdenv.mkDerivation {
    pname = name;
    version = rev;

    src = fetchFromGitHub {
      inherit rev sha256;
      owner = "TheGreatMcPain";
      repo = name;
    };

    nativeBuildInputs = [gtk3];
    propagatedBuildInputs = [breeze-icons hicolor-icon-theme];

    installPhase = ''
      rm -rf README.md LICENSE demo.png
      mkdir -p $out/share/themes/Gruvbox-Material-Dark
      cp -r themes/${variant}/* $out/share/themes/Gruvbox-Material-Dark
      mkdir -p $out/share/icons/Gruvbox-Material-Dark
      cp -r icons/Gruvbox-Material-Dark/* $out/share/icons/Gruvbox-Material-Dark
      gtk-update-icon-cache $out/share/icons/Gruvbox-Material-Dark
    '';

    dontDropIconThemeCache = true;

    meta = with lib; {
      description = "Gruvbox Material for GTK";
      homepage = "https://github.com/TheGreatMcPain/gruvbox-material-gtk";
      license = licenses.mit;
      platforms = platforms.unix;
      maintainers = [];
    };
  }