nixos/pkgs/gruvbox-material-gtk.nix

{
  lib,
  stdenv,
  fetchFromGitHub,
  hiDPI ? false,
}: let
  lock = builtins.fromJSON (builtins.readFile ../flake.lock);
  variant =
    if hiDPI
    then "Gruvbox-Material-Dark-HIDPI"
    else "Gruvbox-Material-Dark";
in
  stdenv.mkDerivation rec {
    pname = lock.nodes.gruvbox-material-gtk.locked.repo;
    version = lock.nodes.gruvbox-material-gtk.locked.rev;

    src = fetchFromGitHub {
      owner = lock.nodes.gruvbox-material-gtk.locked.owner;
      repo = lock.nodes.gruvbox-material-gtk.locked.repo;
      rev = lock.nodes.gruvbox-material-gtk.locked.rev;
      sha256 = lock.nodes.gruvbox-material-gtk.locked.narHash;
    };

    installPhase = ''
      mkdir -p $out/share/themes/gruvbox-material
      rm -rf README.md LICENSE demo.png icons
      cp -r themes/${variant}/* $out/share/themes/gruvbox-material
    '';

    meta = with lib; {
      description = "Gruvbox Material for GTK";
      homepage = "https://github.com/sainnhe/gruvbox-material-gtk";
      license = licenses.mit;
      platforms = platforms.unix;
      maintainers = [];
    };
  }