95 lines
3.1 KiB
Nix
95 lines
3.1 KiB
Nix
{pkgs, ...}: {
|
||
imports = [
|
||
../hardware/intel-nuc.nix
|
||
];
|
||
config = {
|
||
boot.loader.systemd-boot.enable = true;
|
||
boot.loader.efi.canTouchEfiVariables = true;
|
||
|
||
networking.hostName = "cerithium-telescopium";
|
||
networking.networkmanager.enable = true;
|
||
|
||
users.extraUsers.kodi.isNormalUser = true;
|
||
|
||
services.logind.extraConfig = "IdleAction=ignore";
|
||
|
||
services.xserver.enable = true;
|
||
services.xserver.desktopManager.kodi.enable = true;
|
||
services.xserver.displayManager.setupCommands = ''
|
||
/run/current-system/sw/bin/xset -dpms
|
||
/run/current-system/sw/bin/xset s off
|
||
'';
|
||
services.xserver.desktopManager.kodi.package = let
|
||
REpo-AiO = pkgs.fetchFromGitHub {
|
||
owner = "Collabsvito";
|
||
repo = "REpo-AiO";
|
||
rev = "c88a6de";
|
||
hash = "sha256-3FeMPAMXvVwbQXmjz6HYo5QAbrI4x3mkVNTLIco56K4=";
|
||
};
|
||
|
||
rtlGroupPlugin = pkgs.kodiPackages.buildKodiAddon rec {
|
||
pname = "rtl+";
|
||
namespace = "plugin.video.rtlgroup.de";
|
||
version = "1.1.6";
|
||
|
||
src = pkgs.fetchzip {
|
||
url = "file://${REpo-AiO}/MATRIX/${namespace}/${namespace}-${version}+matrix.1.zip";
|
||
hash = "sha256-tknTHae9dRQ1oO8rtgqSzxC7DzbVHa2VhbddWBqNVOI=";
|
||
};
|
||
|
||
patchPhase = ''
|
||
sed 's/Cryptodome/Crypto/g' -i resources/lib/common.py
|
||
'';
|
||
};
|
||
|
||
netflixPlugin = pkgs.kodiPackages.netflix.overrideAttrs rec {
|
||
version = "1.22.3";
|
||
src = pkgs.fetchFromGitHub {
|
||
owner = "CastagnaIT";
|
||
repo = "plugin.video.netflix";
|
||
rev = "v${version}";
|
||
sha256 = "sha256-8NGj8n1p8euqYYdPDSeFh2ZE9lly5ThSmg69yXY3Te8=";
|
||
};
|
||
};
|
||
in
|
||
pkgs.kodi.passthru.withPackages (kodiPkgs:
|
||
with kodiPkgs; [
|
||
youtube
|
||
inputstream-adaptive
|
||
rtlGroupPlugin
|
||
netflixPlugin
|
||
joystick
|
||
# Amazon VOD
|
||
# Arte Mediathek
|
||
# Disney+
|
||
# media.ccc.de
|
||
# RocketBeansTV
|
||
# twitch
|
||
# ZDF Mediathek
|
||
]);
|
||
services.xserver.displayManager.autoLogin.enable = true;
|
||
services.xserver.displayManager.autoLogin.user = "kodi";
|
||
|
||
networking.firewall.allowedTCPPorts = [8080];
|
||
|
||
# This may be needed to force Lightdm into 'autologin' mode.
|
||
# Setting an integer for the amount of time lightdm will wait
|
||
# between attempts to try to autologin again.
|
||
services.xserver.displayManager.lightdm.autoLogin.timeout = 3;
|
||
|
||
# services.cage = {
|
||
# enable = true;
|
||
# program = "${pkgs.kodi-wayland}/bin/kodi-standalone";
|
||
# user = "kodi";
|
||
# };
|
||
|
||
# This value determines the NixOS release from which the default
|
||
# settings for stateful data, like file locations and database versions
|
||
# on your system were taken. It‘s perfectly fine and recommended to leave
|
||
# this value at the release version of the first install of this system.
|
||
# Before changing this value read the documentation for this option
|
||
# (e.g. man configuration.nix or on https://nixos.org/nixos/options.html).
|
||
system.stateVersion = "23.11"; # Did you read the comment?
|
||
};
|
||
}
|