{
  lib,
  fetchFromGitHub,
  rustPlatform,
  clangStdenv,
  gtk3,
  xorg,
  perl,
  openssl,
  speechd,
  libxkbcommon,
  libGL,
  wayland,
  ...
}: let
  hashes = (builtins.import ../hashes.nix).boilr;

  rpathLibs = [
    speechd
    openssl
    gtk3
    libxkbcommon
    libGL

    # WINIT_UNIX_BACKEND=wayland
    wayland

    # WINIT_UNIX_BACKEND=x11
    xorg.libXcursor
    xorg.libXrandr
    xorg.libXi
    xorg.libX11
    xorg.libxcb
  ];
in
  rustPlatform.buildRustPackage.override {stdenv = clangStdenv;} {
    pname = "BoilR";
    inherit (hashes) version;

    src = fetchFromGitHub {
      owner = "PhilipK";
      repo = "BoilR";
      rev = "v.${hashes.version}";
      inherit (hashes) hash;
    };

    warning = builtins.trace "Is boilr part of nixpkgs? https://github.com/NixOS/nixpkgs/pull/247991" "";

    inherit (hashes) cargoHash;

    nativeBuildInputs = [perl];

    buildInputs = rpathLibs;

    postInstall = ''
      mkdir -p $out/share/applications
      cp flatpak/io.github.philipk.boilr.desktop $out/share/applications/
      patchelf --add-rpath "${lib.makeLibraryPath rpathLibs}" $out/bin/boilr
    '';

    dontPatchELF = true;

    meta = {
      description = "BoilR automatically adds (almost) all your games to your Steam library (including image art)";
      homepage = "https://github.com/PhilipK/BoilR";
      license = with lib.licenses; [asl20 mit];
      platforms = lib.platforms.linux;
      maintainers = with lib.maintainers; [foolnotion];
    };
  }