nixos/users/malte/home.nix

{
  pkgs,
  lib,
  config,
  nixosConfig,
  nix-colors,
  ...
}: let
  notDeck = !nixosConfig.users.custom.malte.steamDeck;

  wrap = name: pkg: postBuild:
    pkgs.symlinkJoin {
      inherit name postBuild;
      paths = [pkg];
      buildInputs = [pkgs.makeWrapper];
    };

  fixGdk = name: pkg:
    wrap name pkg ''
      wrapProgram $out/bin/${name} --set GDK_BACKEND x11
    '';

  fixElectron = name: pkg:
    wrap name pkg ''
      wrapProgram $out/bin/${name} --add-flags "--enable-features=UseOzonePlatform --ozone-platform=wayland"
    '';

  lutrisWithLibs = pkgs.lutris.override {
    extraLibraries = pkgs:
      with pkgs; [
        xz
        libstdcxx5
        # For Hotline: Miami
        expat
        openal
        nvidia_cg_toolkit
        # For Dead Cells
        # Provides libXss.1
        xorg.libXScrnSaver
      ];
  };
in {
  imports = [
    ./git.nix
    ./shell.nix
    ./kitty.nix
    ./sway.nix
    ./gpg.nix
    ./mail.nix
    ./pass.nix
    ./zathura.nix
    ./taskwarrior.nix
    ./scarlett-solo.nix
    ./cataclysm-dda.nix
    ./kakoune.nix
    ./helix.nix
    ./mpv.nix
    ./broot.nix
    ./hypr.nix
    ../modules/restic-backup.nix
    ../modules/synchronize-calendars.nix
    ../modules/persway.nix
    ../modules/protonmail-bridge.nix
    ../modules/darkman.nix
    ../modules/colors.nix
  ];

  config = {
    settings.sway.enable = notDeck;
    settings.hyprland.enable = notDeck;
    settings.mail.enable = notDeck;
    settings.taskwarrior.enable = notDeck;

    # Define my color schemes
    colorsLight = nix-colors.colorSchemes."gruvbox-light-medium";
    colorsDark = nix-colors.colorSchemes."gruvbox-dark-medium";

    home = {
      packages =
        [
          pkgs.prismlauncher
          pkgs.jq
          pkgs.mosh
          pkgs.wl-clipboard
          lutrisWithLibs
        ]
        ++ (lib.optionals notDeck (with pkgs; [
          aseprite
          darkman
          alejandra
          element-desktop-wayland
          signal-desktop # FIXME: Once it works again? (fixElectron "signal-desktop" signal-desktop)
          (fixGdk "Discord" discord)
          (fixGdk "losslesscut" losslesscut-bin)
          (fixGdk "skypeforlinux" skypeforlinux)
          (pkgs.callPackage ../../pkgs/2i-emulator.nix {})
          (fenix.latest.withComponents [
            "cargo"
            "clippy"
            "rust-src"
            "rustc"
            "rustfmt"
          ])
          (fixElectron "mattermost-desktop" mattermost-desktop)
          cargo-readme
          cargo-edit
          cargo-udeps
          colmena
          feh
          geekbench
          gimp
          gnome3.nautilus
          gnome3.sushi
          gnome.simple-scan
          helvum
          hledger
          inkscape
          kbdlight
          libnotify
          libreoffice-fresh
          logisim
          mensa
          nickel
          patchelf
          pavucontrol
          pdftk
          pkgs."2a-emulator"
          ponymix
          pulseaudio
          pulseeffects-pw
          python3
          qt5ct
          qucs
          qucs-s
          rtorrent
          screenfetch
          sshfs
          tdesktop
          unar
          unison
          vlc
          vscode
          xdg_utils
          xournalpp
          yt-dlp # youtube-dl alternative that doesn't suck
          wev
        ]));

      sessionVariables = lib.mkIf notDeck {
        LEDGER_FILE = "/home/${config.home.username}/ledger/current.journal";
        MOZ_USE_XINPUT2 = "1";
      };

      # Use default US, so that games don't get too confused. But let me
      # switch to a more comfortable workman layout!
      keyboard = {
        layout = "us,us";
        variant = ",workman";
        options = ["compose:rctrl" "grp:alt_space_toggle" "grp_led:caps"];
      };

      # Use some german units and formats but with the english language!
      language = {
        base = "en_US.UTF-8";
        address = "de_DE.UTF-8";
        measurement = "de_DE.UTF-8";
        monetary = "de_DE.UTF-8";
        name = "de_DE.UTF-8";
        paper = "de_DE.UTF-8";
        telephone = "de_DE.UTF-8";
        time = "de_DE.UTF-8";
      };
    };

    # Make sure firefox is my default browser
    programs.firefox.enable = true;

    programs.obs-studio = lib.mkIf notDeck {
      enable = true;
      plugins = [
        pkgs.obs-studio-plugins.wlrobs
        #pkgs.obs-studio-plugins.v4l2sink
      ];
    };

    # Configure restic backups
    services.restic = {
      enable = true;
      paths = [
        "/home/malte/Documents"
        "/home/malte/Lieder"
        "/home/malte/Pictures"
        "/home/malte/Tasks"
        "/home/malte/Uni"
        "/home/malte/helden"
        "/home/malte/ledger"
        "/home/malte/timewarrior"
        "/home/malte/vimwiki"
        "/home/malte/.local/share/cataclysm-dda"
      ];
    };

    # Configure calendar synchronization
    services.synchronize-calendars = lib.mkIf notDeck {
      enable = true;
      user = "malte";
      passwordFile = nixosConfig.sops.secrets."radicale-password".path;
      defaultCalendar = "Malte";
    };

    # TODO: Merge with Marie's part
    systemd.user.mounts."home-malte-to\\x2dbe\\x2dprinted" = lib.mkIf notDeck {
      Unit = {
        Description = "Directory that prints everything";
      };
      Install = {
        WantedBy = ["default.target"];
      };
      Mount = {
        What = "sftp@faunus-ater:/srv/to-be-printed";
        Where = "/home/malte/to-be-printed";
        Type = "fuse.sshfs";
        Options = "IdentityFile=/run/secrets/sftp-key";
      };
    };

    services.protonmailBridge.enable = notDeck;

    services.darkman.enable = notDeck;

    fonts.fontconfig.enable = notDeck;

    services.mpris-proxy.enable = notDeck;
    services.pasystray.enable = notDeck;

    home.file.".yubico/authorized_yubikeys".text = "malte:ccccccvblrrf";

    home.stateVersion = "18.09";
  };
}